;                         HP 3000 DIAGNOSTICS SUITE
;
; The HP Diagnostics Suite executes all of the diagnostics relevant to
; verification of proper SIMH operation.  It should be run to confirm operation
; of the HP3000 simulator before release.  Because some diagnostics are expected
; to give failures, comparison of the output log with a "known-good" log should
; be performed to judge simulator compliance.
;
; Invocation:
;
;    hp3000 diag-suite [ <path-to-diagnostics> ]
;
; If <path-to-diagnostics> is null, the current directory is assumed.  The path
; must end with a backslash if it is specified and must not contain embedded
; spaces, even if it is quoted.


; Capture the suite execution console log.

set -N console log=DIAG-SUITE.log


; Report the simulator version and starting time.

echo
echo
echo Run started on %DATE_MMM% %DATE_DD%, %DATE_YYYY% at %TIME_HH%:%TIME_MM%:%TIME_SS%
echo
show version


; Establish the initial environment.

echo
echo Configuring the simulation environment.

set CPU III,512K,CIS

break delay 30 milliseconds



;  *******************************
;  *                             *
;  *  HP 3000 Diagnostics Suite  *
;  *                             *
;  *******************************

echo
echo
echo
echo -------------------------
echo HP 3000 Diagnostics Suite
echo -------------------------
echo


; CPU diagnostic section 1 (D420A).

do %1CPU-S1.inc %1


; CPU diagnostic section 2 (D420A1).

do %1CPU-S2.inc %1


; CPU diagnostic section 3 (D420A2).

do %1CPU-S3.inc %1


; CPU diagnostic section 4 (D420A3).

do %1CPU-S4.inc %1


; CPU diagnostic section 5 (D420A4).

do %1CPU-S5.inc %1


; CPU diagnostic sections 6-14 (D420A5-D420A13).

do %1CPU-S6-S14.inc %1


; CPU Extended Instruction Set diagnostic (D431A).

do %1CPU-EIS.inc %1


; CPU COBOL II Extension Instruction Set diagnostic (D441A).

do %1CPU-CIS1.inc %1


; CPU COBOL II Extension Instruction Set diagnostic (D442A).

do %1CPU-CIS2.inc %1


; Terminal Data Interface diagnostic (D427A).

do %1ATCD.inc %1


; Terminal Control Interface diagnostic (D438A).

do %1ATCC.inc %1


; Memory Pattern Test diagnostic (D421A).

do %1MEMPAT.inc %1


; Selector Channel Maintenance Board diagnostic (D429A).

do %1SCMB.inc %1


; Selector Channel diagnostic (D429A).

do %1SEL.inc %1


; Multiplexer Channel diagnostic (D422A).

do %1MPX.inc %1


; System Clock/Fault Logging Interface diagnostic (D426A).

do %1CLK.inc %1


; 7905 Cartridge Disc diagnostic (D419A), user interaction.

do %1DS-UI.inc %1


; 7905 Cartridge Disc diagnostic (D419A), multiple unit, short pass.

do %1DS-MU-S.inc %1


; 7905 Cartridge Disc diagnostic (D419A), multiple unit, long pass.

do %1DS-MU-L.inc %1


; 7970E Nine-Track Magnetic Tape diagnostic (D433A), user interaction.

do %1MS-UI-E.inc %1


; 7970E Nine-Track Magnetic Tape diagnostic (D433A), multiple unit.

do %1MS-MU-E.inc %1


; 7970B Nine-Track Magnetic Tape diagnostic (D433A), user interaction.

do %1MS-UI-B.inc %1


; 7970B Nine-Track Magnetic Tape diagnostic (D433A), multiple unit.

do %1MS-MU-B.inc %1


; Universal Interface diagnostic (D435A).

do %1UI.inc %1



; Diagnostics suite run is complete.
;
; Exit the simulator.

echo
echo
echo
echo ------------------------------
echo Diagnostics Suite Run Complete
echo ------------------------------
echo
echo Run ended on %DATE_MMM% %DATE_DD%, %DATE_YYYY% at %TIME_HH%:%TIME_MM%:%TIME_SS%
echo

exit