; Load DUS-III from the tape.


; Set up the log(s).

set -N console log=D7970.S45.log
set -N console debug=D7970-debug.S45.log

; set imba debug=csrw;data
set gic  debug=xfer
set cpp  debug=opnd
set ma   debug=cmd;inco


; Establish the initial environment.
;
; Tape must be REALTIME to place erase gap at BOT.
; Otherwise fails Step 112 because BOT and Tape Mark both assert.
;
; Reel size must be set.  Otherwise, Step 219 fails to detect EOT.

echo
echo Configuring the simulation environment.

set CPU 512K,CIS

set console DEL=177

set IMBA ENABLED

set GIC CHANNEL=12
set MA  CHANNEL=12,REALTIME

; Temporarily reduce the tape length to speed up Step 220 (write gaps to EOT).
; set MA0 REEL=600
set MA0 CAPACITY=2
set MA1 REEL=600
set MA2 REEL=600
set MA3 REEL=600

break delay 30 milliseconds


echo
echo
echo -----------------------------
echo Diagnostic Utility System III
echo -----------------------------
echo
echo Loading DUS-III.


; Cold load the DUS-III tape.

attach -e -r MS0 DUS-III.tape
boot MS0


echo
echo Configuring the diagnostic.

deposit SWCH 2


; Load and start the diagnostic.
;
; The diagnostic loads from tape and then waits for a <CR>.

echo
echo Starting the diagnostic.

reply "\r" delay 2 seconds

go until "\r\n:"  ; reply "AID\r"
go until "\r\n> " ; reply "LOAD D7970S45\r"


; Correct the AID bug that uses the wrong DRT format.
;
; The DEPOSITs exchange the LOAD Q+2 and LLBL 153 instructions.

deposit 01.037541 033553
deposit 01.037545 041402


; Execute diagnostic sections 4-5.

go until "\r\n>7880 " ; reply "RUN\r"

go until "7970E CHANNEL NUMBER? " ; reply "12\r"
go until "7970E DEVICE NUMBER? "  ; reply "0\r"
go until "NUMBER OF PASSES? "     ; reply "1\r"


; Respond to "MOUNT A TAPE WITH WRITE RING ON EACH UNIT TO BE TESTED."
;            "SET OTHERS OFFLINE, TYPE GO."

attach -n MA0 scratch.0.tape
; attach -n MA1 scratch.1.tape
; attach -n MA2 scratch.2.tape
; attach -n MA3 scratch.3.tape

; go until ">" ; reply "TEST 3\r"
go until ">" ; reply "GO\r"


; Respond to "UNIT 0 WILL BE TESTED."
;            " IF OK TYPE 0, ELSE 1? "

go until "? " ; reply "0\r"


; Respond to "TO OUTPUT MESSAGES TO: LP TYPE 0, CONSOLE 1? "

go until "? " ; reply "1\r"


; Exit

go until "\r\n>"      ; reply "EXIT\r"
go until "\r\n>7880 " ; reply "LIST R,STEP\r"
go until "\r\n>7880 " ; reply "EXIT\r"
go until "?"          ; reply "YES\r"

go until "\r\n:"

detach MA0
; detach MA1
; detach MA2
; detach MA3

; delete scratch.0.tape
; delete scratch.1.tape
; delete scratch.2.tape
; delete scratch.3.tape

exit