; Set up a read on the ADCC.
; The first parameter specifies the port number (default = 1).
; Echo characters to the screen.
; End on CR or BREAK.
; (Note that we cannot read from port 0 because AID is reading from it!)
;
;
; Load DUS-III from the tape.


; Set up the log(s).

set -N console log=ADCCREAD.log
set -N console debug=ADCCREAD-debug.log

set imba debug=csrw;data
set adcc debug,nodebug=pserv
set cpp  debug


; Establish the initial environment.

echo
echo Configuring the simulation environment.

set CPU 512K,CIS

set console DEL=177

set IMBA ENABLED

break delay 30 milliseconds


; Set up the ADCC.

set ADCC REALTIME

if "%1" == "" set env PORT=1
if "%1" != "" set env PORT=%1

attach ADCC 1054

! start E:\Simulation\QCTerm\qcterm.exe F:\Simulation\HP 700\Config\mux.qct

set ADCC LINEORDER=%PORT%;ALL
set ADCC CONNECT


echo
echo
echo -----------------------------
echo Diagnostic Utility System III
echo -----------------------------
echo
echo Loading DUS-III.


; Cold load the DUS-III tape.

attach -e -r MS0 DUS-III.tape
boot MS0


echo
echo Configuring the diagnostic.

deposit SWCH 2


; Load and start the diagnostic.
;
; The diagnostic loads from tape and then waits for a <CR>.

echo
echo Starting the diagnostic.

reply "\r" delay 2 seconds

go until "\r\n:" ; reply "AID\r"


; read characters from ADCC port 1
;
; CC(0) = 98--H (Secondary 1 = reset | 8 bit)
; CC(0) = --1CH (Secondary 2 = enable echo | DCD | DSR)
; CC(1) = 0818H (Secondary 6 = xmit 9600 baud | recv 9600 baud)
; CC(2) = 0602H (Secondary 3 = enable mask 2 | disable mask 0)
; CC(3) = 0D--H (Secondary 5 = set special char CR)
; CC(3) = --3EH (Secondary 0 = write '>')
; CC(4) = 0D0AH (Secondary 0 = write CR | write LF)

go until "\r\n> " ; reply '10  DB &AA,60," "\r'
go until "\r\n> " ; reply '20  DB CC,10,0\r'
go until "\r\n> " ; reply '30  ASSIGN CC(0),!981C,!0818,!0602,!0D3E,!0D0A\r'
go until "\r\n> " ; reply '40  LET CHANNEL:=2,DEVICE:=%PORT%\r'
go until "\r\n> " ; reply '50  BSIO II              . INITIALIZATION\r'
go until "\r\n> " ; reply '60  WB !1,CC(0),1        . UART CONTROL\r'
go until "\r\n> " ; reply '70  WB !2,CC(0),1,,,R    . ENABLE ECHO\r'
go until "\r\n> " ; reply '80  WB !6,CC(1),1        . BAUD RATE\r'
go until "\r\n> " ; reply '90  WB !6,CC(1),1,,,R    . BAUD RATE\r'
go until "\r\n> " ; reply '100 IN H\r'
go until "\r\n> " ; reply '110 RSIO\r'
go until "\r\n> " ; reply '120 BSIO EE\r'
go until "\r\n> " ; reply '130 WB !3,CC(2),1        . ENABLE RCV SERVICE MASK\r'
go until "\r\n> " ; reply '140 WB !5,CC(3),1        . SET SP CHAR CR\r'
go until "\r\n> " ; reply '150 WB !0,CC(3),1,,,R    . WRITE >\r'
go until "\r\n> " ; reply '160 WAIT                 . WAIT UNTIL READY\r'
go until "\r\n> " ; reply '170 RB !0,&AA(0),60      . READ CHAR\r'
go until "\r\n> " ; reply '180 JUMP 200             . END SP CHAR\r'
go until "\r\n> " ; reply '190 JUMP 160             . WAIT FOR NEXT CHAR\r'
go until "\r\n> " ; reply '200 RB !1,CC(5),1,,,R    . READ UART STATUS\r'
go until "\r\n> " ; reply '210 WB !0,CC(4),1        . WRITE CR\r'
go until "\r\n> " ; reply '220 WB !0,CC(4),1,,,R    . WRITE LF\r'
go until "\r\n> " ; reply '230 WB !3,CC(2),1,,,R    . DISABLE RCV SERVICE MASK\r'
go until "\r\n> " ; reply '240 IN H\r'
go until "\r\n> " ; reply '250 ESIO\r'
go until "\r\n> " ; reply '260 RSIO EE\r'
go until "\r\n> " ; reply '270 PRINT "MODEM STATUS IS ";!CC(5)\r'
go until "\r\n> " ; reply '280 END\r'

go until "\r\n> " ; reply "RUN\r"
go until "\r\n> " ; reply "LIST B,&AA\r"


; Exit

go until "\r\n> " ; reply "EXIT\r"
go until "?"      ; reply "YES\r"

go until "\r\n:"

exit