; 9-Track Magnetic Tape (7970B, 13181) diagnostic (DSN 112200, 24396-13601_Rev-2326)
;
; Parameter 1 = path to diagnostics
; Parameter 2 = path and filename of diagnostic loader tape

echo
echo
echo -------------------------------------------------
echo DSN 112200 - 9-Track Magnetic Tape (7970B, 13181)
echo -------------------------------------------------
echo
echo Loading the diagnostic.
echo Expect halt 102077 if successful.

deposit A 112200
deposit B 000000
reset
go 120

assert T=102077


; Verify the DSN.

echo
echo Verifying DSN 112200.

deposit M 126
assert T=112200


; Configure the diagnostic.

echo
echo Configuring the diagnostic.
echo Expect halt 102074 if successful.

detach MSC0

set MSC 13181A,REALTIME

attach -N MSC0 scratch.U0.7970.tape
attach -N MSC1 scratch.U1.7970.tape
attach -N MSC2 scratch.U2.7970.tape
attach -N MSC3 scratch.U3.7970.tape

deposit S 102016
reset
go 100

assert T=102074


; Start the diagnostic.

echo
echo Executing the diagnostic.
echo Expect halt 102024 for user intervention.

deposit S 000017
reset
go

assert T=102024


; Respond to "H024 PRESS PRESET (EXT&INT),RUN"

echo
echo [PRESET pressed, RUN pressed]
echo Expect halt 102024 for user intervention.
echo

reset
go

assert T=102024


; Respond to "H024 PRESS PRESET (EXT&INT),RUN"

echo
echo [PRESET pressed, RUN pressed]
echo Expect message "E135 LRCC ERROR" and halt 106035.
echo

reset
go

assert T=106035


; Respond to "E135 LRCC ERROR"

echo
echo Resuming from error.
echo Expect message "E141 CRCC ERROR" and halt 106041.
echo

go

assert T=106041


; Respond to "E141 CRCC ERROR"

echo
echo Resuming from error.
echo Expect halt 106026 for user intervention.
echo

go

assert T=106026


; Respond to "H126 EXCHANGE REELS"

echo
echo [Reels exchanged, RUN pressed]
echo Expect halt 106027 for user intervention.
echo

attach -E MSC0 scratch.U3.7970.tape
attach -E MSC1 scratch.U2.7970.tape
attach -E MSC2 scratch.U1.7970.tape
attach -E MSC3 scratch.U0.7970.tape

go

assert T=106027


; Respond to "H127 SET SW 13 TO LOOP"

echo
echo [RUN pressed]
echo Expect halt 106030 for user intervention.
echo

go

assert T=106030


; Respond to "H130 REMOVE WRITE RING"

echo
echo [Write ring removed, RUN pressed]
echo Expect halt 106031 for user intervention.
echo

attach -E -R MSC0 scratch.U0.7970.tape
go

assert T=106031


; Respond to "H131 REPLACE WRITE RING"

echo
echo [Write ring replaced, RUN pressed]
echo Expect halt 106037 for user intervention.
echo

attach -E MSC0 scratch.U0.7970.tape
go

assert T=106037


; Respond to "H137 PUT TAPE UNIT ON-LINE"

echo
echo [Unit 0 on-line, RUN pressed]
echo Expect halt 106037 for user intervention.
echo

set MSC0 ONLINE
go

assert T=106037


; Respond to "H137 PUT TAPE UNIT ON-LINE"

echo
echo [Unit 1 on-line, RUN pressed]
echo Expect halt 106037 for user intervention.
echo

set MSC1 ONLINE
go

assert T=106037


; Respond to "H137 PUT TAPE UNIT ON-LINE"

echo
echo [Unit 2 on-line, RUN pressed]
echo Expect halt 106037 for user intervention.
echo

set MSC2 ONLINE
go

assert T=106037


; Respond to "H137 PUT TAPE UNIT ON-LINE"

echo
echo [Unit 3 on-line, RUN pressed]
echo Expect halt 102077 for successful completion.
echo

set MSC3 ONLINE
go


; End of the diagnostic.
;
; Verify HLT 77B for a successful pass.

assert T=102077


; Restore the hardware configuration.

detach MSC0
detach MSC1
detach MSC2
detach MSC3

delete scratch.U0.7970.tape
delete scratch.U1.7970.tape
delete scratch.U2.7970.tape
delete scratch.U3.7970.tape

set MSC 13181A,FASTTIME

attach -E -R MSC0 %2