; testing DX, select code 54B

; 7905/06/20/25 Disc diagnostic (DSN = 151403), single unit test

echo
echo
echo ---------------------------------------------
echo DSN 151403 - 7905/06/20/25 Disc (single unit)
echo ---------------------------------------------
echo
echo Loading the diagnostic.
echo Expect halt 102077 if successful.

deposit A 151403
deposit B 000000
reset
go 120

assert T=102077

echo
echo Verifying DSN 151403.

deposit M 126
assert T=151403

echo
echo Configuring the diagnostic.
echo Expect halt 102074 if successful.

set DX0 7905
attach DX0 scratch.U0.7905.disc

deposit S 000054
reset
go 100

assert T=102074

echo
echo Configuring the test parameters.

set console delay=425000
set console halt=H25

deposit S 000004
reset
go

; Respond to "H37 UNIT TABLE: 01 DRIVE(S); 0"
;            "H25 WISH TO CHANGE?"

echo
set console response=NO~m
set console halt=ENTER:
go

; Respond to "ENTER:(U)NIT,(?) ERRS,(H)EAD,(O)UTPUT,(P)ATT,(S)OFT,(C)YL,(M)CPU,(E)XIT"

echo
set console response=H~m
set console halt=H25
go

; Respond to "H62 HEAD TABLE;  UNIT  0  7905A , 02 HEAD(S) 0 1"
;            "H25 WISH TO CHANGE?"

echo
set console response=YES~m
set console halt=H106
go

; Respond to "H106 ENTER HEADS SEPARATED BY COMMAS"

echo
set console response=0,1,2~m
set console halt=H25
go

; Respond to "H62 HEAD TABLE;  UNIT  0  7905A , 03 HEAD(S) 0 1 2"
;            "H25 WISH TO CHANGE?"

echo
set console response=NO~m
set console halt=ENTER:
go

; Respond to "ENTER:(U)NIT,(?) ERRS,(H)EAD,(O)UTPUT,(P)ATT,(S)OFT,(C)YL,(M)CPU,(E)XIT"

echo
set console response=E~m
set console halt=~j

deposit S 000000
go

echo
echo Executing the diagnostic.
echo Expect messages "H121 WARNING-FORMAT SWITCH OFF"
echo and "H65 LONG PASS 0001,HEAD 012,UNIT 0,0000 ERRORS-0000 SOFT"
echo

;;;;;;;;;;
;break 6212
;;;;;;;;;

set console halt=H65 LONG  PASS 0001
go

;;;;;;;;;;;
;nobreak
;set console debug=dxd.log
;set DX debug
;go
;;;;;;;;;;

; Diagnostic complete.  Restore hardware configuration.

detach DX0

! del scratch.U0.7905.disc