; 7905/06/20/25 Disc diagnostic (DSN = 151403), single unit test

echo
echo
echo ---------------------------------------------
echo DSN 151403 - 7905/06/20/25 Disc (single unit)
echo ---------------------------------------------
echo
echo Loading the diagnostic.
echo Expect halt 102077 if successful.

deposit A 151403
deposit B 000000
reset
go 120

assert T=102077


; Verify the DSN.

echo
echo Verifying DSN 151403.

deposit M 126
assert T=151403


; Configure the diagnostic.

echo
echo Configuring the diagnostic.
echo Expect halt 102074 if successful.

set DS0 7905

attach -N DS0 scratch.U0.7905.disc

deposit S 000034
reset
go 100

assert T=102074


; Select the test set.

echo
echo Configuring the test parameters.

deposit S 000004
reset
go until "CHANGE?\r\n"


; Respond to "H37 UNIT TABLE: 01 DRIVE(S); 0
;             H25 WISH TO CHANGE?"

reply "NO\r"
go until "(E)XIT\r"


; Respond to "ENTER:(U)NIT,(?) ERRS,(H)EAD,(O)UTPUT,(P)ATT,(S)OFT,(C)YL,(M)CPU,(E)XIT"

reply "H\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  0  7905A , 02 HEAD(S) 0 1
;             H25 WISH TO CHANGE?"

reply "YES\r"
go until "COMMAS\r\n"


; Respond to "H106 ENTER HEADS SEPARATED BY COMMAS"

reply "0,1,2\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  0  7905A , 03 HEAD(S) 0 1 2
;             H25 WISH TO CHANGE?"

reply "NO\r"
go until "(E)XIT\r"


; Respond to "ENTER:(U)NIT,(?) ERRS,(H)EAD,(O)UTPUT,(P)ATT,(S)OFT,(C)YL,(M)CPU,(E)XIT"

reply "E\r"
deposit S 000000
go until "\n"


; Start the diagnostic.

echo
echo Executing the diagnostic.
echo Expect messages "H121 WARNING-FORMAT SWITCH OFF"
echo and "H65 LONG PASS 0001,HEAD 012,UNIT 0,0000 ERRORS-0000 SOFT"
echo

;;;;;;;;;;
;break 6212
;;;;;;;;;

go until "SOFT\r\n"


;;;;;;;;;;;
;nobreak
;set console debug=dsd.log
;set DS debug
;go
;;;;;;;;;;


; End of the diagnostic.
;
; Restore the hardware configuration.

detach DS0
delete scratch.U0.7905.disc