; 7905/06/20/25 Disc diagnostic (DSN 151403, 24396-13601_Rev-2326), multiple unit test

echo
echo
echo -----------------------------------------------
echo DSN 151403 - 7905/06/20/25 Disc (multiple unit)
echo -----------------------------------------------
echo
echo Loading the diagnostic.
echo Expect halt 102077 if successful.

deposit A 151403
deposit B 000000
reset
go 120

assert T=102077


; Verify the DSN.

echo
echo Verifying DSN 151403.

deposit M 126
assert T=151403


; Configure the diagnostic.

echo
echo Configuring the diagnostic.
echo Expect halt 102074 if successful.

set DS0 7905
set DS1 7906
set DS2 7920
set DS3 7925
set DS4 7905
set DS5 7906
set DS6 7920
set DS7 7925

attach -N DS0 scratch.U0.7905.disc
attach -N DS1 scratch.U1.7906.disc
attach -N DS2 scratch.U2.7920.disc
attach -N DS3 scratch.U3.7925.disc
attach -N DS4 scratch.U4.7905.disc
attach -N DS5 scratch.U5.7906.disc
attach -N DS6 scratch.U6.7920.disc
attach -N DS7 scratch.U7.7925.disc

deposit S 000034
reset
go 100

assert T=102074


; Select the test set.

echo
echo Configuring the test parameters.

deposit S 000004
reset
go until "CHANGE?\r\n"


; Respond to "H37 UNIT TABLE: 01 DRIVE(S); 0
;             H25 WISH TO CHANGE?"

reply "YES\r"
go until "COMMAS\r\n"


; Respond to "H34 ENTER UNIT NUMBERS(0-7)SEPARATED BY COMMAS"

reply "0,1,2,3,4,5,6,7\r"
go until "CHANGE?\r\n"


; Respond to "H37 UNIT TABLE: 08 DRIVE(S); 0 1 2 3 4 5 6 7
;             H25 WISH TO CHANGE?"

reply "NO\r"
go until "(E)XIT\r\n"


; Respond to "ENTER:(U)NIT,(?) ERRS,(H)EAD,(O)UTPUT,(P)ATT,(S)OFT,(C)YL,(M)CPU,(E)XIT"

reply "H\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE...
;             H25 WISH TO CHANGE?"

reply "YES\r"
go until "COMMAS\r\n"


; Respond to "H132 TYPE UNITS YOU WISH TO CHANGE SEPERATED BY COMMAS"

reply "0,1,4,5\r"
go until "COMMAS\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  0  7905A , 02 HEAD(S) 0 1
;             H106 ENTER HEADS SEPARATED BY COMMAS"

reply "0,1,2\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  0  7905A , 03 HEAD(S) 0 1 2
;             H25 WISH TO CHANGE?"

reply "NO\r"
go until "COMMAS\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  1  7906A , 02 HEAD(S) 0 1
;             H106 ENTER HEADS SEPARATED BY COMMAS"

reply "0,1,2,3\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  1  7906A , 04 HEAD(S) 0 1 2 3
;             H25 WISH TO CHANGE?"

reply "NO\r"
go until "COMMAS\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  4  7905A , 02 HEAD(S) 0 1
;             H106 ENTER HEADS SEPARATED BY COMMAS"

reply "0,1,2\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  4  7905A , 03 HEAD(S) 0 1 2
;             H25 WISH TO CHANGE?"

reply "NO\r"
go until "COMMAS\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  5  7906A , 02 HEAD(S) 0 1"
;            "H106 ENTER HEADS SEPARATED BY COMMAS"

reply "0,1,2,3\r"
go until "CHANGE?\r\n"


; Respond to "H62 HEAD TABLE;  UNIT  5  7906A , 04 HEAD(S) 0 1 2 3"
;            "H25 WISH TO CHANGE?"

reply "NO\r"
go until "(E)XIT\r\n"


; Respond to "ENTER:(U)NIT,(?) ERRS,(H)EAD,(O)UTPUT,(P)ATT,(S)OFT,(C)YL,(M)CPU,(E)XIT"

reply "E\r"
deposit S 000000
go until "\n"


; Start the diagnostic.

echo
echo Executing the diagnostic.
echo Expect messages "H121 WARNING-FORMAT SWITCH OFF"
echo and "H65 LONG PASS 0008,HEAD 012345678,UNIT 7,0000 ERRORS-0000 SOFT,MULTI-UNIT"
echo

go until "MULTI-UNIT\r\n"


; End of the diagnostic.
;
; Restore the hardware configuration.

detach DS0
detach DS1
detach DS2
detach DS3
detach DS4
detach DS5
detach DS6
detach DS7

delete scratch.U0.7905.disc
delete scratch.U1.7906.disc
delete scratch.U2.7920.disc
delete scratch.U3.7925.disc
delete scratch.U4.7905.disc
delete scratch.U5.7906.disc
delete scratch.U6.7920.disc
delete scratch.U7.7925.disc