; 12821 ICD Disc Interface diagnostic (DSN 103024, 24396-13601_Rev-2326)

echo
echo
echo -------------------------------------
echo DSN 103024 - 12821 ICD Disc Interface
echo -------------------------------------
echo
echo Loading the diagnostic.
echo Expect halt 102077 if successful.

deposit A 103024
deposit B 000000
reset
go 120

assert T=102077


; Verify the DSN.

echo
echo Verifying DSN 103024.

deposit M 126
assert T=103024


; Configure the diagnostic.
;
; Set PCHAR to suppress BEL characters in messages.

echo
echo Configuring the diagnostic.

set DA DIAGNOSTIC,ADDRESS=5
set DC DIAGNOSTIC,ADDRESS=7
; set MA DIAGNOSTIC

set CONSOLE PCHAR=23400

deposit S 000000
reset
go 100 until "CODE.. "


; Respond to "IS THE FIRST CARD IN SELECT CODE 43B?
;             IF YES, INPUT CARRIAGE RETURN
;             OTHERWISE, INPUT THE CORRECT SELECT CODE.. "

echo [CR entered]

reply "\r"
go until " ... "


; Respond to "INPUT THE LAST OCTAL DIGIT OF THE BUS
;             ADDRESS (0-7 DERIVED FROM S1-S3) ... "

reply "5\r"
go until "... "


; Respond to "IS THE SECOND CARD IN SELECT CODE 44B?
;             IF YES, INPUT CARRIAGE RETURN
;             IF NO SECOND CARD, INPUT 77B
;             IF DIAGNOSTIC GUESSED INCORRECTLY AND THERE IS
;             A SECOND CARD, ENTER CORRECT SELECT CODE... "

echo [CR entered]

reply "\r"
go until "... "


; Respond to "INPUT THE LAST OCTAL DIGIT OF THE BUS
;             ADDRESS (0-7 DERIVED FROM S1-S3) ... "

reply "7\r"
go until "? "


; Start the diagnostic.
;
; Respond to "PROGRAM OPTIONS:
;
;
;                 CR  - CARRIAGE RETURN- (DEFAULT) EXECUTE DIAG.
;                       FROM TEST 0.
;
;                  N  - BEGIN EXECUTION FROM TEST N
;
;                 LN  - LOOP ON TEST N
;                       (TOGGLE SW BIT 15 TO REGAIN CONTROL)
;
;                  E  - EXIT PROGRAM WITH HLT77
;                       (PRESS RUN TO RE-ENTER PROGRAM)
;
;                  F  - FORCE TESTING TO SECOND BOARD
;
;                  G  - GO BACK AND RETEST BOARD ONE
;
;                  R  - GO BACK TO RECONFIGURATION SECTION
;
;
;             ? "

echo [CR entered]
echo
echo Executing the diagnostic.
echo
echo Expect message "PRESS HALT,PRESET,RUN WITHIN 10 SECONDS !".

reply "\r"
go until "10 SECONDS !"


; Respond to " PRESS HALT,PRESET,RUN WITHIN 10 SECONDS !"
;
; This prompt needs a bit more time before taking action, as some setup
; is done after the prompt.  If the delay is not present, Test 10 fails
; by looping forever.

echo
echo [PRESET pressed, RUN pressed]
echo Expect message "TESTING COMPLETED ON SELECT CODE 43B".
echo    followed by "PRESS HALT,PRESET,RUN WITHIN 10 SECONDS !".

go for 2 seconds

reset
go until "10 SECONDS !"


; Respond to " PRESS HALT,PRESET,RUN WITHIN 10 SECONDS !"
;
; This prompt needs a bit more time before taking action, as some setup
; is done after the prompt.  If the delay is not present, Test 10 fails
; by looping forever.

echo
echo [PRESET pressed, RUN pressed]
echo Expect message "TESTING COMPLETED ON SELECT CODE 44B".
echo    followed by "(T15)..DI TO HP-IB TO DI TEST PASSES !".
echo
echo Then expect halt 102077 for successful completion.

go for 2 seconds

reset
go until "? "


; Respond to "? "

reply "E\r"
go


; End of the diagnostic.
;
; Verify HLT 77B for a successful pass.

assert T=102077


; Restore the hardware configuration.

set DA HPIB
set DC HPIB
; set MA HPIB

set CONSOLE PCHAR=23600